define a = Character("Anita", color = "#aaaa00", callback = speaker("a"), image = "anita")

label start:
    stop music fadeout 1.0
    scene bg room
    with Dissolve(1.0)

    $ success, error = set_model_capabilities()

    if not success:
        call failure(error) from _call_failure
        return

    play music ["zeropage_ambiphonic303chilloutmix.mp3",
                "zeropage_ambientdance.mp3",
                "zeropage_ambiose.mp3" ] fadeout 0.5 fadein 0.5

    show anita happy with dissolve

    python:
        response = fetch_llm(_('Start the conversation.'))[0]
        emotion, line = parse_emotion(response)

    a "[line]"

    while True:
        python:
            message = renpy.input(prompt = _("What do you say to her?"))
            response = fetch_llm(message)
            i = 0

        while i < len(response):
            python:
                r = response[i].strip()

            if r != '':
                $ emotion, line = parse_emotion(r)

                if emotion is not None:
                    show expression f'anita {emotion}'

                a "[line]"

            $ i += 1

    return


label failure(error):
    """Alas! Figuring out the capabilities of the configured model failed with the following error.

    [error]

    Unfortunately the program cannot continue, returning to the main menu."""

    return
